SRC\zlaref.f
#lines: 331   size: 12 Kb   creation: 18/01/2006 23:36:04   last modification: 08/05/2008 18:38:23   attribute: ARCH    Find   Reload   
1:
2:
3:
4:
5:
6:
7:
8:
9:
10:
11:
12:
13:
14:
15:
16:
17:
18:
19:
20:
21:
22:
23:
24:
25:
26:
27:
28:
29:
30:
31:
32:
33:
34:
35:
36:
37:
38:
39:
40:
41:
42:
43:
44:
45:
46:
47:
48:
49:
50:
51:
52:
53:
54:
55:
56:
57:
58:
59:
60:
61:
62:
63:
64:
65:
66:
67:
68:
69:
70:
71:
72:
73:
74:
75:
76:
77:
78:
79:
80:
81:
82:
83:
84:
85:
86:
87:
88:
89:
90:
91:
92:
93:
94:
95:
96:
97:
98:
99:
100:
101:
102:
103:
104:
105:
106:
107:
108:
109:
110:
111:
112:
113:
114:
115:
116:
117:
118:
119:
120:
121:
122:
123:
124:
125:
126:
127:
128:
129:
130:
131:
132:
133:
134:
135:
136:
137:
138:
139:
140:
141:
142:
143:
144:
145:
146:
147:
148:
149:
150:
151:
152:
153:
154:
155:
156:
157:
158:
159:
160:
161:
162:
163:
164:
165:
166:
167:
168:
169:
170:
171:
172:
173:
174:
175:
176:
177:
178:
179:
180:
181:
182:
183:
184:
185:
186:
187:
188:
189:
190:
191:
192:
193:
194:
195:
196:
197:
198:
199:
200:
201:
202:
203:
204:
205:
206:
207:
208:
209:
210:
211:
212:
213:
214:
215:
216:
217:
218:
219:
220:
221:
222:
223:
224:
225:
226:
227:
228:
229:
230:
231:
232:
233:
234:
235:
236:
237:
238:
239:
240:
241:
242:
243:
244:
245:
246:
247:
248:
249:
250:
251:
252:
253:
254:
255:
256:
257:
258:
259:
260:
261:
262:
263:
264:
265:
266:
267:
268:
269:
270:
271:
272:
273:
274:
275:
276:
277:
278:
279:
280:
281:
282:
283:
284:
285:
286:
287:
288:
289:
290:
291:
292:
293:
294:
295:
296:
297:
298:
299:
300:
301:
302:
303:
304:
305:
306:
307:
308:
309:
310:
311:
312:
313:
314:
315:
316:
317:
318:
319:
320:
321:
322:
323:
324:
325:
326:
327:
328:
329:
330:
331:
 
      SUBROUTINE ZLAREF( TYPE, A, LDA, WANTZ, Z, LDZ, BLOCK, IROW1,
     $                   ICOL1, ISTART, ISTOP, ITMP1, ITMP2, LILOZ,
     $                   LIHIZ, VECS, V2, V3, T1, T2, T3 )
*
*  -- ScaLAPACK routine (version 1.7) --
*     Univ. of Tennessee, Univ. of California Berkeley, NAG Ltd.,
*     Courant Institute, Argonne National Lab, and Rice University
*     May 28, 1999
*
*     .. Scalar Arguments ..
      LOGICAL            BLOCK, WANTZ
      CHARACTER          TYPE
      INTEGER            ICOL1, IROW1, ISTART, ISTOP, ITMP1, ITMP2, LDA,
     $                   LDZ, LIHIZ, LILOZ
      COMPLEX*16         T1, T2, T3, V2, V3
*     ..
*     .. Array Arguments ..
      COMPLEX*16         A( LDA, * ), VECS( * ), Z( LDZ, * )
*     ..
*
*  Purpose
*  =======
*
*  ZLAREF applies one or several Householder reflectors of size 3
*     to one or two matrices (if column is specified) on either their
*     rows or columns.
*
*  Arguments
*  =========
*
*  TYPE    (global input) CHARACTER*1
*          If 'R': Apply reflectors to the rows of the matrix
*              (apply from left)
*          Otherwise: Apply reflectors to the columns of the matrix
*          Unchanged on exit.
*
*  A       (global input/output) COMPLEX*16 array, (LDA,*)
*          On entry, the matrix to receive the reflections.
*          The updated matrix on exit.
*
*  LDA     (local input) INTEGER
*          On entry, the leading dimension of A.  Unchanged on exit.
*
*  WANTZ   (global input) LOGICAL
*          If .TRUE., then apply any column reflections to Z as well.
*          If .FALSE., then do no additional work on Z.
*
*  Z       (global input/output) COMPLEX*16 array, (LDZ,*)
*          On entry, the second matrix to receive column reflections.
*          This is changed only if WANTZ is set.
*
*  LDZ     (local input) INTEGER
*          On entry, the leading dimension of Z.  Unchanged on exit.
*
*  BLOCK   (global input) LOGICAL
*          If .TRUE., then apply several reflectors at once and read
*             their data from the VECS array.
*          If .FALSE., apply the single reflector given by V2, V3,
*             T1, T2, and T3.
*
*  IROW1   (local input/output) INTEGER
*          On entry, the local row element of A.
*          Undefined on output.
*
*
*  ICOL1   (local input/output) INTEGER
*          On entry, the local column element of A.
*          Undefined on output.
*
*  ISTART  (global input) INTEGER
*          Specifies the "number" of the first reflector.  This is
*              used as an index into VECS if BLOCK is set.
*              ISTART is ignored if BLOCK is .FALSE..
*
*  ISTOP   (global input) INTEGER
*          Specifies the "number" of the last reflector.  This is
*              used as an index into VECS if BLOCK is set.
*              ISTOP is ignored if BLOCK is .FALSE..
*
*  ITMP1   (local input) INTEGER
*          Starting range into A.  For rows, this is the local
*              first column.  For columns, this is the local first row.
*
*  ITMP2   (local input) INTEGER
*          Ending range into A.  For rows, this is the local last
*              column.  For columns, this is the local last row.
*
*  LILOZ
*  LIHIZ   (local input) INTEGER
*          These serve the same purpose as ITMP1,ITMP2 but for Z
*              when WANTZ is set.
*
*  VECS    (global input) COMPLEX*16 array of size 3*N (matrix size)
*          This holds the size 3 reflectors one after another and this
*              is only accessed when BLOCK is .TRUE.
*
*  V2
*  V3
*  T1
*  T2
*  T3      (global input/output) COMPLEX*16
*          This holds information on a single size 3 Householder
*              reflector and is read when BLOCK is .FALSE., and
*              overwritten when BLOCK is .TRUE.
*
*  Further Details
*  ===============
*
*  Implemented by:  M. Fahey, May 28, 1999
*
*  =====================================================================
*
*     .. Local Scalars ..
      INTEGER            J, K
      COMPLEX*16         A1, A11, A2, A22, A3, A4, A5, B1, B2, B3, B4,
     $                   B5, H11, H22, SUM, SUM1, SUM2, SUM3, T12, T13,
     $                   T22, T23, T32, T33, TMP1, TMP2, TMP3, V22, V23,
     $                   V32, V33
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           LSAME
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          DCONJG, MOD
*     ..
*     .. Executable Statements ..
*
      IF( LSAME( TYPE, 'R' ) ) THEN
         IF( BLOCK ) THEN
            DO 30 K = ISTART, ISTOP - MOD( ISTOP-ISTART+1, 3 ), 3
               V2 = VECS( ( K-1 )*3+1 )
               V3 = VECS( ( K-1 )*3+2 )
               T1 = VECS( ( K-1 )*3+3 )
               V22 = VECS( ( K-1 )*3+4 )
               V32 = VECS( ( K-1 )*3+5 )
               T12 = VECS( ( K-1 )*3+6 )
               V23 = VECS( ( K-1 )*3+7 )
               V33 = VECS( ( K-1 )*3+8 )
               T13 = VECS( ( K-1 )*3+9 )
               T2 = T1*V2
               T3 = T1*V3
               T22 = T12*V22
               T32 = T12*V32
               T23 = T13*V23
               T33 = T13*V33
               DO 10 J = ITMP1, ITMP2 - MOD( ITMP2-ITMP1+1, 2 ), 2
                  A1 = A( IROW1, J )
                  A2 = A( IROW1+1, J )
                  A3 = A( IROW1+2, J )
                  A4 = A( IROW1+3, J )
                  A5 = A( IROW1+4, J )
                  B1 = A( IROW1, J+1 )
                  B2 = A( IROW1+1, J+1 )
                  B3 = A( IROW1+2, J+1 )
                  B4 = A( IROW1+3, J+1 )
                  B5 = A( IROW1+4, J+1 )
                  SUM1 = DCONJG( T1 )*A1 + DCONJG( T2 )*A2 +
     $                   DCONJG( T3 )*A3
                  A( IROW1, J ) = A1 - SUM1
                  H11 = A2 - SUM1*V2
                  H22 = A3 - SUM1*V3
                  TMP1 = DCONJG( T1 )*B1 + DCONJG( T2 )*B2 +
     $                   DCONJG( T3 )*B3
                  A( IROW1, J+1 ) = B1 - TMP1
                  A11 = B2 - TMP1*V2
                  A22 = B3 - TMP1*V3
                  SUM2 = DCONJG( T12 )*H11 + DCONJG( T22 )*H22 +
     $                   DCONJG( T32 )*A4
                  A( IROW1+1, J ) = H11 - SUM2
                  H11 = H22 - SUM2*V22
                  H22 = A4 - SUM2*V32
                  TMP2 = DCONJG( T12 )*A11 + DCONJG( T22 )*A22 +
     $                   DCONJG( T32 )*B4
                  A( IROW1+1, J+1 ) = A11 - TMP2
                  A11 = A22 - TMP2*V22
                  A22 = B4 - TMP2*V32
                  SUM3 = DCONJG( T13 )*H11 + DCONJG( T23 )*H22 +
     $                   DCONJG( T33 )*A5
                  A( IROW1+2, J ) = H11 - SUM3
                  A( IROW1+3, J ) = H22 - SUM3*V23
                  A( IROW1+4, J ) = A5 - SUM3*V33
                  TMP3 = DCONJG( T13 )*A11 + DCONJG( T23 )*A22 +
     $                   DCONJG( T33 )*B5
                  A( IROW1+2, J+1 ) = A11 - TMP3
                  A( IROW1+3, J+1 ) = A22 - TMP3*V23
                  A( IROW1+4, J+1 ) = B5 - TMP3*V33
   10          CONTINUE
               DO 20 J = ITMP2 - MOD( ITMP2-ITMP1+1, 2 ) + 1, ITMP2
                  SUM = DCONJG( T1 )*A( IROW1, J ) +
     $                  DCONJG( T2 )*A( IROW1+1, J ) +
     $                  DCONJG( T3 )*A( IROW1+2, J )
                  A( IROW1, J ) = A( IROW1, J ) - SUM
                  H11 = A( IROW1+1, J ) - SUM*V2
                  H22 = A( IROW1+2, J ) - SUM*V3
                  SUM = DCONJG( T12 )*H11 + DCONJG( T22 )*H22 +
     $                  DCONJG( T32 )*A( IROW1+3, J )
                  A( IROW1+1, J ) = H11 - SUM
                  H11 = H22 - SUM*V22
                  H22 = A( IROW1+3, J ) - SUM*V32
                  SUM = DCONJG( T13 )*H11 + DCONJG( T23 )*H22 +
     $                  DCONJG( T33 )*A( IROW1+4, J )
                  A( IROW1+2, J ) = H11 - SUM
                  A( IROW1+3, J ) = H22 - SUM*V23
                  A( IROW1+4, J ) = A( IROW1+4, J ) - SUM*V33
   20          CONTINUE
               IROW1 = IROW1 + 3
   30       CONTINUE
            DO 50 K = ISTOP - MOD( ISTOP-ISTART+1, 3 ) + 1, ISTOP
               V2 = VECS( ( K-1 )*3+1 )
               V3 = VECS( ( K-1 )*3+2 )
               T1 = VECS( ( K-1 )*3+3 )
               T2 = T1*V2
               T3 = T1*V3
               DO 40 J = ITMP1, ITMP2
                  SUM = DCONJG( T1 )*A( IROW1, J ) +
     $                  DCONJG( T2 )*A( IROW1+1, J ) +
     $                  DCONJG( T3 )*A( IROW1+2, J )
                  A( IROW1, J ) = A( IROW1, J ) - SUM
                  A( IROW1+1, J ) = A( IROW1+1, J ) - SUM*V2
                  A( IROW1+2, J ) = A( IROW1+2, J ) - SUM*V3
   40          CONTINUE
               IROW1 = IROW1 + 1
   50       CONTINUE
         ELSE
            DO 60 J = ITMP1, ITMP2
               SUM = DCONJG( T1 )*A( IROW1, J ) +
     $               DCONJG( T2 )*A( IROW1+1, J ) +
     $               DCONJG( T3 )*A( IROW1+2, J )
               A( IROW1, J ) = A( IROW1, J ) - SUM
               A( IROW1+1, J ) = A( IROW1+1, J ) - SUM*V2
               A( IROW1+2, J ) = A( IROW1+2, J ) - SUM*V3
   60       CONTINUE
         END IF
      ELSE
*
*        Do column transforms
*
         IF( BLOCK ) THEN
            DO 90 K = ISTART, ISTOP - MOD( ISTOP-ISTART+1, 3 ), 3
               V2 = VECS( ( K-1 )*3+1 )
               V3 = VECS( ( K-1 )*3+2 )
               T1 = VECS( ( K-1 )*3+3 )
               V22 = VECS( ( K-1 )*3+4 )
               V32 = VECS( ( K-1 )*3+5 )
               T12 = VECS( ( K-1 )*3+6 )
               V23 = VECS( ( K-1 )*3+7 )
               V33 = VECS( ( K-1 )*3+8 )
               T13 = VECS( ( K-1 )*3+9 )
               T2 = T1*V2
               T3 = T1*V3
               T22 = T12*V22
               T32 = T12*V32
               T23 = T13*V23
               T33 = T13*V33
               DO 70 J = ITMP1, ITMP2
                  SUM = T1*A( J, ICOL1 ) + T2*A( J, ICOL1+1 ) +
     $                  T3*A( J, ICOL1+2 )
                  A( J, ICOL1 ) = A( J, ICOL1 ) - SUM
                  H11 = A( J, ICOL1+1 ) - SUM*DCONJG( V2 )
                  H22 = A( J, ICOL1+2 ) - SUM*DCONJG( V3 )
                  SUM = T12*H11 + T22*H22 + T32*A( J, ICOL1+3 )
                  A( J, ICOL1+1 ) = H11 - SUM
                  H11 = H22 - SUM*DCONJG( V22 )
                  H22 = A( J, ICOL1+3 ) - SUM*DCONJG( V32 )
                  SUM = T13*H11 + T23*H22 + T33*A( J, ICOL1+4 )
                  A( J, ICOL1+2 ) = H11 - SUM
                  A( J, ICOL1+3 ) = H22 - SUM*DCONJG( V23 )
                  A( J, ICOL1+4 ) = A( J, ICOL1+4 ) - SUM*DCONJG( V33 )
   70          CONTINUE
               IF( WANTZ ) THEN
                  DO 80 J = LILOZ, LIHIZ
                     SUM = T1*Z( J, ICOL1 ) + T2*Z( J, ICOL1+1 ) +
     $                     T3*Z( J, ICOL1+2 )
                     Z( J, ICOL1 ) = Z( J, ICOL1 ) - SUM
                     H11 = Z( J, ICOL1+1 ) - SUM*DCONJG( V2 )
                     H22 = Z( J, ICOL1+2 ) - SUM*DCONJG( V3 )
                     SUM = T12*H11 + T22*H22 + T32*Z( J, ICOL1+3 )
                     Z( J, ICOL1+1 ) = H11 - SUM
                     H11 = H22 - SUM*DCONJG( V22 )
                     H22 = Z( J, ICOL1+3 ) - SUM*DCONJG( V32 )
                     SUM = T13*H11 + T23*H22 + T33*Z( J, ICOL1+4 )
                     Z( J, ICOL1+2 ) = H11 - SUM
                     Z( J, ICOL1+3 ) = H22 - SUM*DCONJG( V23 )
                     Z( J, ICOL1+4 ) = Z( J, ICOL1+4 ) -
     $                                 SUM*DCONJG( V33 )
   80             CONTINUE
               END IF
               ICOL1 = ICOL1 + 3
   90       CONTINUE
            DO 120 K = ISTOP - MOD( ISTOP-ISTART+1, 3 ) + 1, ISTOP
               V2 = VECS( ( K-1 )*3+1 )
               V3 = VECS( ( K-1 )*3+2 )
               T1 = VECS( ( K-1 )*3+3 )
               T2 = T1*V2
               T3 = T1*V3
               DO 100 J = ITMP1, ITMP2
                  SUM = T1*A( J, ICOL1 ) + T2*A( J, ICOL1+1 ) +
     $                  T3*A( J, ICOL1+2 )
                  A( J, ICOL1 ) = A( J, ICOL1 ) - SUM
                  A( J, ICOL1+1 ) = A( J, ICOL1+1 ) - SUM*DCONJG( V2 )
                  A( J, ICOL1+2 ) = A( J, ICOL1+2 ) - SUM*DCONJG( V3 )
  100          CONTINUE
               IF( WANTZ ) THEN
                  DO 110 J = LILOZ, LIHIZ
                     SUM = T1*Z( J, ICOL1 ) + T2*Z( J, ICOL1+1 ) +
     $                     T3*Z( J, ICOL1+2 )
                     Z( J, ICOL1 ) = Z( J, ICOL1 ) - SUM
                     Z( J, ICOL1+1 ) = Z( J, ICOL1+1 ) -
     $                                 SUM*DCONJG( V2 )
                     Z( J, ICOL1+2 ) = Z( J, ICOL1+2 ) -
     $                                 SUM*DCONJG( V3 )
  110             CONTINUE
               END IF
               ICOL1 = ICOL1 + 1
  120       CONTINUE
         ELSE
            DO 130 J = ITMP1, ITMP2
               SUM = T1*A( J, ICOL1 ) + T2*A( J, ICOL1+1 ) +
     $               T3*A( J, ICOL1+2 )
               A( J, ICOL1 ) = A( J, ICOL1 ) - SUM
               A( J, ICOL1+1 ) = A( J, ICOL1+1 ) - SUM*DCONJG( V2 )
               A( J, ICOL1+2 ) = A( J, ICOL1+2 ) - SUM*DCONJG( V3 )
  130       CONTINUE
         END IF
      END IF
      RETURN
*
*     End of ZLAREF
*
      END